ESP8266 based Temperature Data logger using Arduino

ESP8266 is a wifi module controlled by simple AT commands. This post describes the usage of a web api developed developed by thingspeak.com to plot data on the web.

First of all you need to register on the thingspeak website and obtain an API key. The Key can be found once you login in into the website

Connect the ESP8266 module to your Arduino board as following. Please note that Software serial is used to send and receive data to the Wifi module from the Arduino so that any input/output pin can be used for interfacing with the module.

Following code is used to upload the temperate sensor data to the thingspeak website. User need to edit the API key value to match the one obtained when you login. It is also assumed that you are connected to a router and the network is accessible.

Note: A good idea is to read the IP address of your module using AT+CIFSR command. Also can check the connectivity by pinging the IP obtained from another computer. Use ping and check the response.

// esp8266_test.ino
//
// Plot LM35 data on thingspeak.com using an Arduino and an ESP8266 WiFi
// module.
#include <SoftwareSerial.h>
#include <stdlib.h>

// LED
int ledPin = 13;
// LM35 analog input
int lm35Pin = A0;

// replace with your channel's thingspeak API key
String apiKey = "ZP1PZO62773HXWVU";

// connect 10 to TX of Serial USB
// connect 11 to RX of serial USB
SoftwareSerial ser(10, 11); // RX, TX

// this runs once
void setup() {
// initialize the digital pin as an output.
pinMode(ledPin, OUTPUT);

// enable debug serial
Serial.begin(9600);
// enable software serial
ser.begin(9600);

// reset ESP8266
ser.println("AT+RST");
}
// the loop
void loop() {

// blink LED on board
digitalWrite(ledPin, HIGH);
delay(200);
digitalWrite(ledPin, LOW);

// read the value from LM35.
// read 10 values for averaging.
int val = 0;
for(int i = 0; i < 10; i++) {
val += analogRead(lm35Pin);
delay(500);
}

// convert to temp:
// temp value is in 0-1023 range
// LM35 outputs 10mV/degree C. ie, 1 Volt => 100 degrees C
// So Temp = (avg_val/1023)*5 Volts * 100 degrees/Volt
float temp = val*50.0f/1023.0f;

// convert to string
char buf[16];
String strTemp = dtostrf(temp, 4, 1, buf);

Serial.println(strTemp);

// TCP connection
String cmd = "AT+CIPSTART=\"TCP\",\"";
cmd += "184.106.153.149"; // api.thingspeak.com
cmd += "\",80";
ser.println(cmd);

if(ser.find("Error")){
Serial.println("AT+CIPSTART error");
return;
}

// prepare GET string
String getStr = "GET /update?api_key=";
getStr += apiKey;
getStr +="&field1=";
getStr += String(strTemp);
getStr += "\r\n\r\n";

// send data length
cmd = "AT+CIPSEND=";
cmd += String(getStr.length());
ser.println(cmd);

if(ser.find(">")){
ser.print(getStr);
}
else{
ser.println("AT+CIPCLOSE");
// alert user
Serial.println("AT+CIPCLOSE");
}

// thingspeak needs 15 sec delay between updates
delay(16000);
}

Connect LM35 temperature sensor using the pinout shown below. A0 pin should be connected to the out pin of LM35.

.

Once the connection is made, connect the programming cable and upload the code to your Arduino board.

Open a webbrowser and login into the thingspeak website using the appropriate credentials, Then browse to the public channel to see the graphical representation of the data uploaded. Thingspeak also has several customisation options. You will become familiar with these if you are exploring the settings section in their website.